Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel


Beranda >> Tutorial Excel Compute Expert >> Cara Menghitung di Excel >> Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel



Di tutorial ini, kamu akan mempelajari cara membuat ranking/peringkat di excel dengan berbagai rumus ranking excel.

Ketika bekerja dengan angka di excel, kita terkadang ingin tahu ranking angka kita jika dibandingkan besarannya dengan angka-angka lainnya. Untuk mendapatkan ranking tersebut, kita sebaiknya memahami cara menghitung ranking di excel dengan benar. Ada beberapa rumus dan fitur yang kamu bisa gunakan untuk membantumu dalam proses perhitungan ranking dari suatu angka di excel.

Ingin tahu apa saja rumus dan fitur tersebut dan bagaimana cara merangking di excel dalam situasi-situasi tertentu? Baca tutorial ini sampai ke bagian terakhirnya!







Cara Membuat Ranking/Peringkat di Excel Secara Normal

Excel menyediakan rumus-rumus khusus yang bisa kita gunakan untuk merangking angka-angka kita. Rumus-rumus tersebut adalah RANK dan RANK.EQ.

Kedua rumus ini mempunyai kegunaan yang sama dan cara penulisan yang juga hampir sama. Secara resminya, RANK.EQ adalah versi terperbaharui dari RANK (kita mulai bisa menggunakannya sejak excel 2010) walaupun sepertinya tidak ada perbedaan signifikan di antara keduanya.

Untuk menggunakan RANK dan RANK.EQ, kamu bisa menuliskan mereka dalam bentuk seperti ini.

RANK

= RANK ( angka_yang_diranking , cell_range_angka , [ urutan ] )


RANK.EQ

= RANK.EQ ( angka_yang_diranking , cell_range_angka , [ urutan ] )


Tidak terlalu berbeda, bukan, bentuk penulisannya? Kamu perlu memasukkan input angka yang kamu hitung rankingnya dan cell range berisi angka-angka yang ingin kamu bandingkan untuk rankingnya (cell rangenya juga harus berisi angka yang ingin kamu hitung rankingnya).

Jika perlu, masukkan juga input apakah kamu mau merangking angka dalam urutan besar ke kecil atau kecil ke besar. Masukkan input 0 untuk besar ke kecil dan 1 untuk kecil ke besar. Jika kamu tidak memasukkan input apapun, maka excel akan mengasumsikan kamu menginginkan ranking dalam urutan besar ke kecil.

Gunakan RANK atau RANK.EQ dan kamu akan mendapatkan hasil yang sama dari keduanya! Kamu bisa lihat contoh implementasi mereka di excel di screenshot berikut.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus RANK dan RANK.EQ untuk Merangking Secara Normal

Di contoh tersebut, kita ingin merangking wilayah-wilayahnya berdasarkan banyak cabang yang kita punya. Kita gunakan RANK dan RANK.EQ untuk membantu kita dalam proses perhitungan rangkingnya.

Seperti yang kamu lihat, kita tuliskan RANK dan RANK.EQnya dalam bentuk penulisan yang telah kita diskusikan sebelumnya. Kita masukkan input banyak cabang dari wilayah yang ingin kita rangking dan cell range dari kolom banyak cabangnya. Karena kita ingin mendapatkan ranking kita dalam urutan kecil ke besar, kita masukkan 1 sebagai input urutan RANK dan RANK.EQnya.

Sebagai hasilnya, kita mendapatkan ranking yang sama dari rumus RANK dan RANK.EQ yang kita tuliskan!



Cara Membuat Ranking/Peringkat di Excel dengan Menggunakan Fitur Sort

Jika kamu ingin merangking angka-angkamu sambil menempatkan mereka dalam urutan rankingnya, gunakan fitur pengurutan data di excel. Setelah mengurutkan angka-angkamu, kamu seharusnya dapat mengetahui ranking mereka dengan mudah dengan cara melihat posisi mereka.

Kamu bisa mengurutkan angka-angkamu dalam urutan yang kamu inginkan (besar ke kecil atau kecil ke besar). Cara melakukan proses pengurutannya sendiri cukup simpel seperti yang bisa kamu lihat pada langkah-langkahnya di bawah ini.

  1. Sorot cell range kolom yang berisi angka-angka yang ingin kamu urutkan

    Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Cara Ranking Menggunakan Fitur Sort, Langkah 1

  2. Pergi ke tab Data dan klik tombol Sort Smallest to Largest (kecil ke besar) atau Sort Largest to Smallest (besar ke kecil) di sini. Tentunya kamu sebaiknya memilih tombol yang sesuai dengan urutan ranking yang kamu inginkan

    Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Cara Ranking Menggunakan Fitur Sort, Langkah 2

  3. Di dialog box yang muncul, ada dua opsi pengurutan yang bisa kamu pilih. Pilih “Expand the selection” jika kamu ingin mengurutkan kolom-kolom di dekat kolom angkanya juga berdasarkan pengurutan kolom angkamu. Pilih “Continue with the current selection” jika kamu hanya ingin mengurutkan kolom angka yang kamu sedang sorot.

    Klik tombol Sort setelah kamu memilih opsi pengurutan yang kamu inginkan

    Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Cara Ranking Menggunakan Fitur Sort, Langkah 3

  4. Selesai! Kamu telah mengurutkan kolom angkamu! Sekarang, kamu seharusnya bisa melihat ranking angka-angkamu dalam urutan yang kamu inginkan dengan mudah

    Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Cara Ranking Menggunakan Fitur Sort, Langkah 4




Cara Membuat Ranking/Peringkat Data Duplikat di Excel Tanpa Melompati Peringkat Setelah Itu

Kamu bisa lihat pada contoh implementasi RANK dan RANK.EQ kalau kita melompati ranking setelah merangking duplikasi dengan menggunakan kedua rumusnya. Sebagai ilustrasi, jika kita merangking angka 3, 3, dan 5, maka 5 di sana akan mendapatkan ranking 3. Ini karena RANK dan RANK.EQ menghitung banyak duplikasinya ketika mereka merangking angka setelah duplikasinya tersebut.

Bagaimana jika dalam kasus 3, 3, dan 5, kita ingin merangking angka 5 di sana dengan 2, bukan 3? Bagaimana kita bisa membuat excel tidak melompati peringkat setelah ia merangking angka terduplikasi yang kita punya?



Salah satu cara yang bisa kita gunakan adalah mengkombinasikan SUMPRODUCT dan COUNTIF untuk merangking angka kita.

Berikut bentuk penulisan umum SUMPRODUCT dan COUNTIF di excel untuk merangking angka tanpa melompati peringkat.

= SUMPRODUCT ( ( angka_yang_dirangking <= cell_range_angka ) / COUNTIF ( cell_range_angka , cell_range_angka ) )


Penulisan rumus ini mengasumsikan kita ingin merangking angka kita dalam urutan besar ke kecil. Jika kita ingin merangking angka kita dalam urutan kecil ke besar, ganti simbol <=nya dengan >=.

Mau mempelajari logika di balik penulisan rumusnya? Kita akan mendiskusikannya melalui contoh implementasinya di bawah ini agar kamu dapat memahaminya dengan lebih mudah!

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus SUMPRODUCT dan COUNTIF untuk Merangking Tanpa Melompati

Di sini, kita gunakan set data yang sama dengan yang kita gunakan pada contoh implementasi RANK dan RANK.EQ sebelumnya. Seperti yang kamu lihat, dengan mengkombinasikan SUMPRODUCT dan COUNTIF, kita bisa membuat excel tidak melompati peringkat setelah ia merangking angka terduplikasi.

Seperti apa logika di balik penulisan rumusnya sehingga kita bisa mendapatkan hasil ranking yang kita inginkan tersebut? Pertama, mari kita lihat bagian awal dari input SUMPRODUCT kita sebelum COUNTIF.

Di sana, kita memasukkan input (angka_yang_dirangking<=cell_range_angka). Kita memasukkan input seperti itu karena kita ingin memfilter angka-angka yang kurang dari atau sama dengan angka kita. Karena kita menghitung ranking dalam urutan besar ke kecil pada contohnya, kita akan mendapatkan ranking angkanya dengan memfilter seperti ini dulu.

Setelah kita membandingkan angka kita dengan cell rangenya, kita akan dapatkan hasil array TRUE/FALSE dari operasi perbandingannya. Kita mendapatkan TRUE jika angka di cell rangenya lebih dari atau sama dengan angka kita. Kita mendapatkan FALSE jika angka di cell rangenya kurang dari angka kita.

Pada contoh, kita mendapatkan array TRUE/FALSE seperti ini dari input untuk wilayah A dengan banyak cabang 15.

{ TRUE , TRUE , TRUE , FALSE , TRUE , TRUE , TRUE , FALSE , FALSE , TRUE , FALSE , FALSE , FALSE , FALSE , FALSE }


Kita bagi array ini dengan hasil COUNTIF kita.

Di COUNTIFnya, kita masukkan input cell range angka kita sebanyak dua kali. Ini karena kita ingin mendapatkan array yang berisi banyak dari setiap angka di cell range angkanya. Input cell range COUNTIFnya adalah cell range angka kita dan kriteria perhitungannya adalah setiap angka dari cell rangenya tersebut.

Dari COUNTIF yang kita tuliskan di contohnya, kita mendapatkan array seperti ini untuk setiap wilayahnya.

{ 3 , 1 , 1 , 1 , 1 , 3 , 3 , 1 , 1 , 1 , 2 , 1 , 1 , 2 , 1 }


Hasilnya sama untuk setiap wilayah karena kita memasukkan input cell range angka yang sama ke COUNTIF mereka.

Setelah kita mendapatkan kedua array tersebut, kita bagi mereka dengan menggunakan simbol garis miring yang kita tuliskan di antara mereka. Kita bisa membagi TRUE/FALSE karena TRUE sama saja dengan 1 dan FALSE sama saja dengan 0 di excel.

Karena prinsip pembagian array adalah membagi angka yang sama posisinya, kita dapatkan hasil seperti ini untuk wilayah A dalam contohnya.

{ 0.333 , 1 , 1 , 0 , 1 , 0.333 , 0.333 , 0 , 0 , 1 , 0 , 0 , 0 , 0 , 0 }


Kita jumlahkan semua angka di hasil pembagian arraynya tersebut dengan menggunakan SUMPRODUCT. Kita menggunakan SUMPRODUCT karena ia bisa membantu kita memproses array tanpa perlu menggunakan bentuk rumus array excel.

Untuk wilayah A di contohnya, kita dapatkan 5 setelah kita menjumlahkan hasil pembagian arraynya. Lima tersebut adalah ranking banyak cabang wilayah A jika dibandingkan dengan banyak cabang dari wilayah-wilayah lainnya! Karena kita mendapatkan desimal dari angka-angka yang memiliki duplikasi dalam arraynya, kita tidak perlu melompati peringkat setelah merangking mereka.

Sebagai catatan tambahan, kamu mungkin menyadari kita menggunakan simbol dolar di penulisan rumus pada contohnya. Ini karena kita menyalin ke bawah penulisan rumus pertama kita untuk mendapatkan semua penulisan rumus yang kita butuhkan.

Menggunakan simbol dolar tersebut akan membuat input cell range angkanya tidak bergerak dan hal inilah yang kita butuhkan. Ini karena kita perlu menggunakan input cell range angka yang sama dalam semua penulisan rumus kita di sana.



Cara Membuat Ranking/Peringkat di Excel dengan Ranking Rata-rata untuk Data Duplikat

Bagaimana jika kita tidak masalah dengan pelompatan peringkatnya tapi kita ingin merangking angka terduplikasinya dengan ranking rata-rata? Ini berarti jika kita merangking 3 dalam kelompok 3, 3, dan 5, rankingnya akan menjadi 1,5 (rata-rata dari ranking 1 dan 2 untuk kedua angka 3nya) bukan 1 (ranking tertinggi di antara ranking 1 dan 2 untuk kedua angka 3nya).

Jika kamu menginginkan hal seperti itu, maka kamu bisa menggunakan RANK.AVG agar kamu mendapatkan ranking rata-rata untuk angka terduplikasimu. Bentuk penulisan umum dari RANK.AVG di excel mirip dengan bentuk penulisan dari RANK dan RANK.EQ.

= RANK.AVG ( angka_yang_dirangking , cell_range_angka , [ urutan ] )


Dan berikut contoh implementasinya di excel. Seperti yang kamu lihat di sini, RANK.AVG merangking angka terduplikasi dengan ranking rata-rata mereka, bukan ranking tertingginya.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus RANK.AVG untuk Mendapatkan Ranking Rata-rata bagi Angka Terduplikasi

Ketika kamu perlu merangking angka terduplikasimu dengan ranking rata-rata, gunakan RANK.AVG!



Cara Membuat Ranking di Excel agar Tidak Ganda

Dari semua rumus yang sudah kita gunakan untuk merangking angka terduplikasi, kita mendapatkan ranking yang sama untuk angkanya tersebut. Bagaimana jika kita ingin merangking mereka dengan ranking yang berbeda agar semua angka kita bisa mendapatkan ranking yang unik? Kita bisa mengkombinasikan RANK dan COUNTIF untuk melakukan proses perhitungan ranking unik tersebut.

Cara penulisan kombinasi RANK dan COUNTIF untuk tujuan mendapatkan ranking unik tadi adalah sebagai berikut.

= RANK ( angka_yang_diranking , cell_range_angka , [ urutan ] ) + COUNTIF ( cell_range_angka_yang_paralel_dengan_angka_yang_dirangking , angka_yang_dirangking ) - 1


Kita tuliskan rumus RANK kita secara normal sembari menambahkan hasil COUNTIF serta mengurangi hasil penambahannya tersebut dengan angka satu.



Di COUNTIF, kita masukkan input cell range angka kita dari angka pertama sampai ke cell berisi angka yang ingin kita rangkingkan. Ini agar kita bisa merangking angka terduplikasi kita dengan unik sesuai dengan berapa kali ia telah muncul sebelumnya. Kita masukkan minus satu juga di sana untuk menyesuaikan hasilnya agar kita bisa mendapatkan ranking yang benar untuk angka-angka kita.

Contoh implementasi kombinasi RANK dan COUNTIF ini di excel adalah sebagai berikut.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus RANK dan COUNTIF untuk Mendapatkan Ranking Unik bagi Angka Terduplikasi

Seperti bisa kamu lihat di sana, kita mendapatkan ranking unik untuk setiap duplikasi angka-angka yang kita punya (15 dan 9). Ini karena kita mengkombinasikan RANK dan COUNTIF untuk mendapatkan ranking kita.

Di COUNTIF, kita masukkan input cell range angka kita dengan menggunakan simbol dolar di koordinat cell pertamanya. Koordinat cell pertama ini adalah cell berisi angka pertama dan koordinat cell yang kedua adalah cell yang paralel dengan angka kita.

Simbol dolar menyebabkan input cell range COUNTIFnya jadi mengikuti ketika kita menyalin penulisan rumus kita. Hal ini membuat kita mendapatkan input cell range yang benar untuk setiap penulisan COUNTIF kita!

Kita tuliskan kombinasi RANK dan COUNTIF kita berdasarkan bentuk penulisan umum yang sudah kita diskusikan sebelumnya. Sebagai hasilnya, kita dapatkan ranking dari semua angka kita secara unik!



Cara Membuat Ranking di Excel untuk Data yang Memenuhi Kriteria Tertentu (RANK IF)

Kita mungkin mempunyai beberapa karakteristik pada angka yang ingin kita rangking. Terkadang, kita ingin merangking angka kita tersebut dalam perbandingannya dengan angka-angka yang memiliki karakteristik yang sama.

Sayangnya, kita tidak mempunyai rumus seperti RANKIF atau RANKIFS untuk membantu kita merangking seperti itu. Akan tetapi, kita bisa gunakan COUNTIFS sebagai alternatif untuk melakukan proses rangking seperti itu.

Berikut bentuk penulisan umum dari COUNTIFS untuk membantu kita membuat ranking dengan menggunakan kriteria tertentu.

= COUNTIFS ( range_data1 , kriteria1 , … , range_angka , “>” & angka_yang_dirangking ) + 1


Seperti biasa, kita masukkan input cell range dan kriteria pada COUNTIFS kita secara berpasangan. Kriteria yang kita masukkan sebagai input hanya akan mengevaluasi data di cell range yang kita masukkan sebagai input sebelumnya.

Untuk merangking angka dalam perbandingannya dengan angka-angka yang memiliki karakteristik yang sama, masukkan karakteristik angkanya sebagai input kriterianya. Kita pasangkan cell range yang relevan dengan setiap karakteristik angka kita agar kita bisa mendapatkan hasil ranking yang tepat.

Kita juga masukkan input cell range yang berisi angka-angka kita beserta perbandingannya dengan angka yang kita rangking sebagai kriterianya. Untuk perbandingannya tersebut, kita masukkan “>“ jika kita menginginkan ranking dalam urutan besar ke kecil. Jika kita menginginkan ranking dalam urutan kecil ke besar, kita masukkan “<”. Kita masukkan juga tanda dan (&) sebagai penghubung antara simbol perbandingannya tersebut dengan angka kita.

Logikanya, semakin sedikit angka yang lebih dari angka yang ingin kita rangking, semakin tinggi peringkat besar ke kecil yang kita dapatkan. Semakin sedikit angka yang kurang dari angka yang ingin kita rangking, semakin tinggi peringkat kecil ke besar yang kita dapatkan.

Kriteria perbandingan tersebut membuat kita mampu menghitung angka-angka kita dengan benar dan mendapatkan ranking berdasarkan hasil perhitungan tersebut. Kita tambahkan hasilnya juga dengan satu dalam penulisan rumus kita agar kita bisa menyesuaikan hasil COUNTIFSnya untuk mendapatkan ranking yang benar.

Untuk pemahaman yang lebih baik mengenai konsep COUNTIFSnya tersebut, berikut contoh implementasinya di excel.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus COUNTIFS untuk Merangking dengan Kriteria

Dalam contoh tersebut, kita ingin merangking kuantitas penjualan kita dalam kelompok minggunya. Ini berarti kita hanya akan membandingkan kuantitasnya tersebut dengan kuantitas penjualan di minggu yang sama untuk mendapatkan rankingnya.

Kita gunakan COUNTIFS untuk membantu kita melakukan proses rangkingnya. Karena minggu adalah kriteria kita di sini, kita masukkan input cell range kolom minggunya dan minggu kuantitas penjualannya tersebut ke COUNTIFS.

Kita juga masukkan input cell range kolom kuantitas penjualannya dan perbandingannya dengan kuantitas penjualan yang kita rangking sebagai kriterianya. Karena kita menginginkan ranking dalam urutan besar ke kecil di sini, kita masukkan “>” sebagai simbol perbandingannya.

Kita lakukan semua itu dan kita dapatkan ranking kuantitas penjualan kita dalam perbandingannya dengan kuantitas penjualan lainnya di minggu yang sama.



Cara Membuat Ranking Persentil di Excel

Perlu membuat ranking angkamu dalam bentuk persentil dalam perbandingannya dengan angka-angka lainnya? Kamu bisa menggunakan PERCENTRANK/PERCENTRANK.INC/PERCENTRANK.EXC untuk membantumu mendapatkan ranking persentil tersebut.

Ranking persentil adalah ranking angkamu dalam perbandingannya dengan besaran angka-angka lainnya dalam bentuk persentase. Skala rankingnya 0 sampai 1. Sebagai ilustrasinya, jika angkamu lebih besar daripada 30% angka-angka lainnya, ia akan mendapatkan ranking persentil 0,3.

PERCENTRANK/PERCENTRANK.INC/PERCENTRANK.EXC akan membuatmu mendapatkan ranking persentil dari angka-angkamu di excel. PERCENTRANK.EXC dan PERCENTRANK.INC adalah versi lebih baru dari PERCENTRANK yang mulai bisa kamu gunakan sejak excel 2010. Akan tetapi, kamu masih bisa juga menggunakan PERCENTRANK jika kamu mau.

Gunakan PERCENTRANK.EXC untuk menerapkan sifat eksklusif pada angka pertama dan terakhir dalam urutan ranking persentilmu. Gunakan PERCENTRANK atau PERCENTRANK.INC untuk menerapkan sifat inklusif kepada angka-angka tersebut.

Berikut adalah bentuk penulisan umum dari ketiga rumusnya di excel.

= PERCENTRANK/PERCENTRANK.INC/PERCENTRANK.EXC ( cell_range_angka , angka_yang_dirangking , [ signifikansi ] )


Ketiga rumus tersebut membutuhkan input yang sama dalam penulisan mereka. Input signifikansi di sana adalah banyak desimal yang kamu inginkan dalam ranking persentilmu. Jika kamu tidak memberikan input apapun untuk signifikansinya, maka excel akan mengasumsikan kamu menginginkan signifikansi sebanyak tiga signifikansi.

Untuk lebih memahami mengenai rumus-rumus ini, berikut contoh implementasi dari mereka di excel.

PERCENTRANK

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus PERCENTRANK untuk Mendapatkan Ranking Persentil

PERCENTRANK.INC

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus PERCENTRANK.INC untuk Mendapatkan Ranking Persentil

PERCENTRANK.EXC

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus PERCENTRANK.EXC untuk Mendapatkan Ranking Persentil

Seperti yang kamu lihat di contohnya, kita mendapatkan ranking persentil yang berbeda dari PERCENTRANK.EXC dan PERCENTRANK/PERCENTRANK.INC. Ini karena perbedaan sifat eksklusif dan inklusif dari ketiga rumusnya.

Gunakan rumus yang benar, salah satu dari PERCENTRANK, PERCENTRANK.INC, atau PERCENTRANK.EXC, berdasarkan kebutuhan perhitungan ranking persentilmu yang kamu punyai!



Cara Membuat Ranking di Excel dengan Mengabaikan Nol

Terkadang, kita mempunyai nol dalam angka-angka kita dan kita ingin mengabaikan mereka dalam proses perhitungan ranking kita. Untuk melakukan hal tersebut di excel, kita bisa mengkombinasikan IF, RANK, dan COUNTIF untuk membantu kita mendapatkan rankingnya.



Berikut bentuk penulisan umum dari kombinasi rumus IF, RANK, dan COUNTIFnya untuk mengabaikan nol dalam proses perhitungan ranking kita. Kita memiliki bentuk penulisan yang berbeda untuk merangking dalam urutan besar ke kecil dan dalam urutan kecil ke besar.

Ranking dalam urutan besar ke kecil

= IF ( angka_yang_dirangking = 0 , “” , IF ( angka_yang_dirangking > 0 , RANK ( angka_yang_dirangking , cell_range_angka ) , RANK ( angka_yang_dirangking , cell_range_angka ) - COUNTIF ( cell_range_angka , 0 ) ) )


Ranking dalam urutan kecil ke besar

= IF ( angka_yang_dirangking = 0 , “” , IF ( angka_yang_dirangking > 0 , RANK ( angka_yang_dirangking , cell_range_angka , 1 ) - COUNTIF ( cell_range_angka , 0 ) , RANK ( angka_yang_dirangking , cell_range_angka , 1 ) ) )


Karena kita ingin mengabaikan nol, kita buat IF kita menghasilkan data kosong jika kita menemukan nol dalam angka-angka kita. Dalam IF, kita gunakan COUNTIF untuk menyesuaikan hasil dari RANK agar nol tidak memberikan efek pada hasilnya. COUNTIFnya menghitung banyaknya nol yang kita punya dalam cell range angka kita.

Jika kita merangking dalam urutan besar ke kecil, kita masukkan input COUNTIF kita dalam skenario jika kita merangking angka negatif. Jika kita merangking dalam urutan kecil ke besar, kita masukkan input COUNTIF kita dalam skenario jika kita merangking angka positif. Kita lakukan ini karena nol memberikan efek pada proses merangking angka negatif dan positif kita dalam urutan ranking yang berbeda.

Berikut contoh implementasi kombinasi IF, RANK, dan COUNTIF tersebut di excel. Kita pisahkan contoh proses merangkingnya berdasarkan urutan besar ke kecil dan urutan kecil ke besar.

Contoh merangking dalam urutan besar ke kecil

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus IF, RANK, dan COUNTIF untuk Merangking Mengabaikan Nol dalam Urutan Besar ke Kecil

Contoh merangking dalam urutan kecil ke besar

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus IF, RANK, dan COUNTIF untuk Merangking Mengabaikan Nol dalam Urutan Kecil ke Besar

Seperti yang bisa kamu lihat di contohnya, kita berhasil mengabaikan nol dalam proses perhitungan ranking kita! Hal ini karena kita menuliskan kombinasi rumus IF, RANK, dan COUNTIF kita dengan benar.

Untuk ranking besar ke kecil, kita tuliskan COUNTIF dalam bagian proses rangking angka negatif dalam IF kita. Dan untuk ranking kecil ke besar, kita tuliskan COUNTIF kita di bagian proses rangking angka positif dalam IF kita. Kita tuliskan rumus RANK kita secara normal di kedua urutan rankingnya.



Cara Membuat Ranking di Excel untuk Angka Positif dan Negatif Secara Terpisah

Perlu merangking angka positif/negatifmu dalam perbandingannya dengan angka-angka positif/negatif lainnya saja? Karena ini menjadi seperti suatu kriteria dalam proses rangkingmu, kamu bisa menggunakan COUNTIFS untuk membantumu. Kombinasikan COUNTIFS dengan IF agar kamu bisa mendapatkan data kosong jika input angkanya bukan angka positif/negatif yang ingin kamu rangking.

Cara mengkombinasikan IF dan COUNTIFS untuk merangking angka positif/negatifmu dalam urutan besar ke kecil/kecil ke besar adalah sebagai berikut.

Merangking angka positif dalam urutan besar ke kecil

= IF ( angka_yang_dirangking > 0 , COUNTIFS ( cell_range_angka , “>” & angka_yang_dirangking ) + 1 , “” )


Merangking angka positif dalam urutan kecil ke besar

= IF ( angka_yang_dirangking > 0 , COUNTIFS ( cell_range_angka , “<“ & angka_yang_dirangking , cell_range_angka , “>0” ) + 1 , “” )


Merangking angka negatif dalam urutan besar ke kecil

= IF ( angka_yang_dirangking < 0 , COUNTIFS ( cell_range_angka , “>” & angka_yang_dirangking , cell_range_angka , “<0” ) + 1 , “” )


Merangking angka negatif dalam urutan kecil ke besar

= IF ( angka_yang_dirangking < 0 , COUNTIFS ( cell_range_angka , “<“ & angka_yang_dirangking ) + 1 , “” )


Kita tempatkan COUNTIFS di dalam IF kita dan membuatnya menjadi hasil TRUE dari IF tersebut. Untuk kondisi logika IFnya, kita masukkan kondisi untuk mengetes apakah angkanya merupakan angka positif/negatif.

Dalam COUNTIFS, kita masukkan kriteria untuk angka-angka di cell range kita berdasarkan urutan ranking yang kita inginkan. Jika kita menginginkan ranking dalam urutan besar ke kecil, kita masukkan kriteria lebih dari (“>”) angka yang kita ingin rangking. Jika kita menginginkan ranking dalam urutan kecil ke besar, kita masukkan input kriteria yang sebaliknya (“<“).

Jika kita merangking angka positif dalam urutan kecil ke besar, kita masukkan input kriteria angka positif di COUNTIFS kita. Hal ini karena mungkin saja angka yang kurang dari angka yang kita rangking adalah angka negatif. Kita lakukan hal yang sama juga jika kita merangking angka negatif dalam urutan besar ke kecil untuk alasan yang sama.

Kita tambahkan juga satu ke hasil COUNTIFS kita agar kita bisa mendapatkan ranking yang benar dari angka positif/negatif kita.

Untuk pemahaman yang lebih baik mengenai konsep kombinasi IF dan COUNTIFSnya, berikut contoh implementasinya di excel.

Merangking angka positif

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus IF dan COUNTIFS untuk Merangking Angka Positif Saja

Merangking angka negatif

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus IF dan COUNTIFS untuk Merangking Angka Negatif Saja

Pada contoh-contoh tersebut, kita merangking angka positif dan negatif kita dalam urutan besar ke kecil. Kita bisa merangking mereka secara terpisah dengan menggunakan kombinasi rumus IF dan COUNTIFS seperti yang kamu lihat di sana.

Ketika kita ingin merangking angka positif saja, kita abaikan sepenuhnya angka negatif dalam proses rangking kita. Begitu juga kebalikannya. Ketika kita ingin merangking angka negatif saja, kita abaikan angka positif sepenuhnya.

Kita tuliskan kombinasi IF dan COUNTIFSnya di contoh-contoh tersebut dengan menggunakan bentuk penulisan yang sudah kita diskusikan sebelumnya. Sebagai hasilnya, kita dapatkan ranking angka positif dan negatif yang kita perlukan!



Cara Membuat Ranking di Excel dengan Nilai Absolut

Daripada merangking angka positif dan negatif kita secara terpisah, kita mungkin ingin merangking nilai absolut mereka secara bersamaan. Ini berarti kita hanya membandingkan nilai angka kita dalam proses rangkingnya, tanpa melihat simbol positif atau negatif dari angka tersebut.

Adakah cara melakukan proses rangking nilai absolut seperti itu di excel? Jawabannya adalah ada. Kita bisa mengkombinasikan SUMPRODUCT dan ABS untuk merangking nilai-nilai absolut dari angka kita secara lebih mudah!



Berikut bentuk penulisan umum dari kombinasi SUMPRODUCT dan ABSnya untuk tujuan proses rangking nilai absolut tersebut.

Merangking nilai absolut dalam urutan dari besar ke kecil

= SUMPRODUCT ( — ( ABS ( angka_yang_dirangking ) < ABS ( cell_range_angka ) ) ) + 1


Merangking nilai absolut dalam urutan dari kecil ke besar

= SUMPRODUCT ( — ( ABS ( angka_yang_dirangking ) > ABS ( cell_range_angka ) ) ) + 1


Dalam penulisan rumus-rumus di atas, kita aplikasikan ABS ke angka dan cell range angka kita dalam SUMPRODUCT. Kita gunakan ABS untuk mendapatkan nilai absolut dari angka yang ingin kita rangking dan angka-angka dalam cell range kita.

Kita bandingkan angka yang kita ingin rangking dengan setiap angka yang kita punya di cell range kita dalam bentuk nilai absolut. Simbol perbandingan yang kita gunakan tergantung dari urutan yang kita inginkan sebagai dasar untuk ranking kita. Kita gunakan simbol “<“ untuk ranking dalam urutan besar ke kecil dan “>” untuk ranking dalam urutan kecil ke besar.

Kita dapatkan array TRUE/FALSE sebagai hasil perbandingan angka yang ingin kita rangking dengan angka-angka lainnya. Kita gunakan juga simbol minus ganda di depan penulisan ABSnya untuk mengubah TRUE/FALSE menjadi angka 1/0.

Kemudian, kita gunakan SUMPRODUCT untuk menjumlahkan satu dan nol dalam arraynya dan lalu menambahkan satu ke hasil penjumlahannya. Dari sana, kita dapatkan ranking nilai absolut dari angka kita dalam urutan yang kita inginkan!

Contoh implementasi kombinasi SUMPRODUCT dan ABS ini adalah sebagai berikut.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus SUMPRODUCT dan ABS untuk Merangking Nilai Absolut

Seperti bisa kamu lihat, dengan menggunakan kombinasi SUMPRODUCT dan ABS, kita bisa mendapatkan ranking dari nilai absolut angka kita!



Cara Membuat Ranking di Cell-Cell yang Tidak Urut

Perlu merangking angka-angka yang berada di cell-cell yang tidak urut? Untuk melakukan proses rangkingnya dengan lancar, kamu perlu mengkombinasikan IF, ISNA, dan RANK dalam proses penulisan rumusmu. Ketika memasukkan input ke RANKnya, kamu perlu memasukkan input hanya cell-cell tidak berurutannya tersebut, bukan cell range angkanya secara keseluruhan.

Berikut bentuk penulisan umum kombinasi IF, ISNA, dan RANK untuk merangking cell-cell yang tidak urut.

= IF ( ISNA ( RANK ( angka_yang_dirangking , ( cell_cell_tidak_urut ) , [ urutan ] ) ) , “” , RANK ( angka_yang_dirangking , ( cell_cell_tidak_urut ) , [ urutan ] ) )


Kita tuliskan RANK kita dalam IF kita dua kali di sini, sebagai input ISNA dan sebagai hasil FALSE dari IFnya. Kita tuliskan RANKnya secara normal kecuali untuk cell-cell tidak berurutan dalam kurungnya yang menggantikan input cell range angka kita.

Kita gunakan IF dan ISNA di sini untuk mengantisipasi error #N/A yang kemungkinan besar muncul. Ketika kita menyalin penulisan rumus kita, cell-cell yang tidak kita masukkan dalam proses rangking kita akan menghasilkan error #N/A. Jadi, untuk merapikan tampilan cellnya, kita ubah error #N/Anya tersebut menjadi data kosong di sini.

Untuk lebih memahami konsep dari penulisan rumus tersebut, berikut contoh implementasinya di excel.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus IF, ISNA, dan RANK untuk Merangking Cell-Cell yang Tidak Urut

Di contohnya tersebut, kita mencoba merangking banyak cabang di lima wilayah (B, E, H, K, dan O) dari lima belas wilayah yang kita punya di sana. Karena banyak cabang kelima wilayah tersebut berada di cell-cell yang tidak berurutan, kita merangkingnya menggunakan kombinasi IF, ISNA, dan RANK.

Kita tuliskan RANK dengan memasukkan input angka yang ingin dirangking dan cell-cell tidak berurutannya. Kita tuliskan di dalam ISNA dan sebagai hasil FALSE dari IF kita. Ketika ISNAnya menghasilkan TRUE (yang berarti kita mendapatkan error #N/A), kita ingin IF kita memberikan hasil data kosong.

Kita lakukan itu semua dan kita akan mendapatkan ranking angka-angka dari cell-cell yang tidak berurutan seperti pada contohnya.



Cara Membuat Ranking di Excel Berdasarkan Kelompok

Mau merangking angkamu berdasarkan perbandingannya dengan angka-angka di kelompok yang sama? Karena kita biasanya mengelompokkan data berdasarkan karakteristik data-datanya, kita bisa gunakan COUNTIFS untuk membantu kita dalam proses rangking ini.

Cara menggunakan COUNTIFS di sini sama dengan cara kita menggunakannya untuk merangking berdasarkan kriteria. Masukkan input cell range data di mana karakteristik kelompoknya berada dan karakteristiknya sendiri sebagai input kriterianya secara berpasangan di dalam COUNTIFSnya. Masukkan inputnya sampai kamu sudah memasukkan semua karakteristik yang mendefinisikan kelompok datamu.

Masukkan juga input cell range angkamu beserta kriteria angkanya. Masukkan input simbol “>” dalam kriteria angkamu jika kamu menginginkan ranking dalam urutan besar ke kecil. Jika kamu menginginkan ranking dalam urutan kecil ke besar, masukkan input simbol “<“.

Lakukan sesuai dengan yang sudah kita diskusikan sebelumnya mengenai proses rangking berdasarkan kriteria dengan menggunakan COUNTIFS. Kamu akan langsung mendapatkan ranking angkamu dalam perbandingannya dengan angka-angka lain di kelompok yang sama!



Cara Membuat Weighted Ranking (Ranking Tertimbang/Terbobot) di Excel

Weighted ranking berarti kamu merangking angkamu dalam perbandingannya dengan ranking angka terkecil dan terbesar dalam angka-angkamu. Jika angkamu lebih dekat dengan angka terbesar, maka ranking angka tersebut seharusnya lebih dekat dengan ranking angka terbesar tersebut. Begitu pula sebaliknya.

Excel tidak mempunyai rumus khusus untuk melakukan proses perhitungan weighted ranking tersebut. Jadi, kita harus membuat rumusnya secara manual dengan menggunakan RANK dan juga MAX dan MIN untuk mendapatkan angka terbesar dan terkecilnya. Kita membutuhkan angka terbesar dan terkecilnya sebagai pembanding untuk angka yang kita rangking.



Bentuk penulisan rumus yang menggabungkan rumus RANK, MAX, dan MINnya adalah sebagai berikut. Kita pisahkan bentuk penulisan untuk ranking dalam urutan besar ke kecil dan kecil ke besar di sini.

Weighted ranking (dalam urutan besar ke kecil)

= 1 + ( MAX ( cell_range_angka ) - angka_yang_diranking ) / ( MAX ( cell_range_angka ) - MIN ( cell_range_angka ) ) * ( RANK ( MIN ( cell_range_angka ) , cell_range_angka ) - 1 )


Weighted ranking (dalam urutan kecil ke besar)

= 1 + ( angka_yang_dirangking - MIN ( cell_range_angka ) ) / ( MAX ( cell_range_angka ) - MIN ( cell_range_angka ) ) * ( RANK ( MAX ( cell_range_angka ) , cell_range_angka , 1 ) - 1 )


Penulisan rumus-rumus di atas terlihat rumit tapi konsep yang mendasari penulisan mereka sebenarnya cukup simpel. Dalam setiap penulisan rumus di atas, kita mencoba membandingkan antara angka yang ingin kita rangking dengan angka terbesar dan terkecilnya.

Untuk ranking dalam urutan besar ke kecil, kita dapatkan selisih antara angka kita dengan angka terbesarnya terlebih dahulu. Lalu, kita bagi selisihnya tersebut dengan selisih antara angka terbesar dan angka terkecilnya.

Setelah kita dapatkan perbandingan selisihnya, kita kalikan dengan ranking besar ke kecil dari angka terkecilnya (yang menjadi angka ranking terbesar dalam urutan tersebut). Kita sesuaikan hasilnya dengan menambah dan menguranginya dengan satu untuk mendapatkan ranking tertimbang/terbobot kita dengan benar. Untuk ranking dalam urutan kecil ke besar, kita lakukan hal yang sama dengan sedikit penyesuaian dalam proses rangking rumusnya.

Untuk memahami lebih baik mengenai rumus-rumus weighted rankingnya tersebut, kamu bisa lihat contoh implementasi mereka di bawah ini.

Weighted ranking (dalam urutan besar ke kecil)

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus RANK, MAX, dan MIN untuk Mendapatkan Weighted Ranking dalam Urutan Besar ke Kecil

Weighted ranking (dalam urutan kecil ke besar)

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus RANK, MAX, dan MIN untuk Mendapatkan Weighted Ranking dalam Urutan Kecil ke Besar

Karena kita memasukkan input cell range yang sama dalam MAX, MIN, dan RANKnya, kita sebaiknya menggunakan simbol dolar pada mereka. Hal ini agar kita dapat menyalin ke bawah penulisan rumus kita tanpa masalah untuk mendapatkan ranking tertimbang dari semua angka kita.

Tuliskan rumusnya dengan benar dengan menggunakan konsep yang kita diskusikan dan kamu seharusnya akan mendapatkan ranking tertimbangmu seperti di contoh!



Cara Membuat Ranking Dinamis di Excel

Apakah kamu sering menambahkan angka baru ke cell range angkamu dan kamu ingin agar rumus RANKmu menyesuaikan hasilnya terhadap penambahan tersebut? Untuk ini, kamu sebaiknya menuliskan kombinasi OFFSET dan COUNTA sebagai input cell range angka di RANKmu.

OFFSET adalah rumus yang bisa memindahkan dan/atau memperlebar cell/cell range yang kita jadikan sebagai inputnya. Di lain pihak, COUNTA adalah rumus yang bisa menghitung banyak data yang kita punya dalam suatu cell range. Dengan mengkombinasikan mereka dalam RANK, kita bisa membuat rumus ranking dinamis yang menyesuaikan hasilnya terhadap angka baru yang kita tambahkan!

Bentuk penulisan umum kombinasi RANK, OFFSET, dan COUNTA adalah sebagai berikut.

= RANK ( angka_yang_dirangking , OFFSET ( cell_pertama_cell_range_angka , 0 , 0 , COUNTA ( cell_range_angka_yang_diperlebar ) , 1 ) , [ urutan ] )


Penulisan rumus ini mengasumsikan kamu ingin merangking angka-angka dalam sebuah cell range kolom, bukan baris.

Di sini, kita masukkan input cell pertama dari cell range angka kita sebagai cell yang ingin kita perlebar dengan menggunakan OFFSET. Kita gunakan COUNTA sebagai input pelebar baris di dalam OFFSETnya. Cell range yang kita masukkan ke COUNTA mencakup cell angka saat ini beserta cell tempat kita akan memasukkan angka baru kita.

Dengan melakukan hal-hal tersebut, ketika kita memasukkan angka baru ke kolom kita, OFFSET akan memperlebar input cell range angka RANKnya! Hal ini membuat ranking angka-angka kita akan otomatis diperbaharui dengan mempertimbangkan perbandingan mereka dengan besaran angka barunya. Jika kita ingin merangking angka barunya juga, kita tinggal menyalinkan penulisan rumus kita kepada mereka untuk melakukan proses rangkingnya.

Berikut contoh implementasi dari kombinasi RANK, OFFSET, dan COUNTAnya.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Kombinasi Rumus RANK, OFFSET, dan COUNTA untuk Merangking Secara Dinamis

Seperti yang bisa kamu lihat, kita gunakan kombinasi rumus RANK, OFFSET, dan COUNTAnya untuk merangking angka kita. Kita merangking angka kita dalam urutan besar ke kecil di sini. Di dalam COUNTAnya, kita masukkan input cell range dari angka pertama kita sampai ke baris terakhir worksheet kita.

Jika kita memasukkan input data wilayah baru di sana, ranking kita akan langsung terperbaharui. Proses pembaharuan ini tidak terjadi jika kita hanya menggunakan RANK dalam penulisan rumus kita.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Pembaharuan Ranking Setelah Penambahan Data

Jika kita memerlukan ranking dari angka-angka barunya juga, kita tinggal menyalin ke bawah penulisan rumus kita.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Hasil Penyalinan Rumus Ranking Dinamis

Cukup berguna jika kamu sering perlu menambahkan angka-angka baru di cell range angkamu, bukan?



Cara Membuat Ranking di Tabel Pivot

Untuk merangking angka-angka di tabel pivotmu, kamu sebaiknya menampilkan label angka beserta angkamu dalam tabel pivotnya terlebih dahulu. Setelah itu, tambahkan variabel angkamu lagi sebagai nilai tambahan di tabelnya dan ubah ia menjadi ranking yang kamu perlukan.



Untuk lebih memahami konsepnya, mari kita lihat bagaimana kita merangking angka-angka di tabel pivot berikut.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Tabel Pivot untuk Contoh Implementasi Merangking di Tabel Pivot

Kita membuat tabel pivotnya tersebut dari tabel data yang kita punya di sebelah kiri. Kita punya wilayah sebagai label angkanya dan kuantitas penjualan sebagai angka kita. Kita buat wilayah menjadi baris tabel pivotnya dan kuantitas penjualan sebagai nilainya.

Untuk merangking kuantitas penjualannya, kita tambahkan nilai kuantitas penjualan lagi di pengaturan dari tabel pivot kita.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Penambahan Variabel Angka di Bagian Nilai Tabel Pivot

Untuk mengubah nilai tambahannya tersebut menjadi ranking, kita klik tombol nilainya untuk masuk ke pengaturannya.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Lokasi Tombol Nilai untuk Masuk ke Pengaturan Ranking

Di dialog box yang muncul, berikan nama untuk variabel rankingmu di tabel pivotnya, misalnya “Ranking”. Lalu, pergi ke tab “Show Data” di sana. Klik dropdown di tengah dan pilih “Rank Smallest to Largest” (kecil ke besar) atau “Rank Largest to Smallest” (besar ke kecil) (tergantung dari urutan ranking yang ingin kamu gunakan).

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Lokasi Boks Teks Nama Nilai, Tab Show Data, dan Pilihan Dropdown Ranking

Lalu, di boks Base Field, pilih label angkamu. Di contoh ini, kita pilih Wilayah pada boksnya tersebut.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Pemilihan Variabel Label Nilai di Boks Base Field

Setelah kamu melakukan semua itu di dialog boxmu, klik OK. Kamu akan langsung mendapatkan ranking dari angka-angka di tabel pivotmu!

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Hasil Ranking di Tabel Pivot



Cara Mendapatkan Nilai Terbesar/Terkecil ke-n di Excel

Perlu mendapatkan nilai terbesar/terkecil ke-n dari angka-angkamu, bukan ranking dari mereka? Kamu bisa mendapatkan nilai tersebut dengan mudah di excel karena ada rumus-rumus khusus yang bisa kamu gunakan untuk mendapatkannya. Rumus-rumus tersebut adlaah LARGE untuk nilai terbesar ke-n dan SMALL untuk nilai terkecil ke-n.

Bentuk penulisan umum dari kedua rumus tersebut di excel adalah sebagai berikut.

LARGE

= LARGE ( cell_range_angka , nth )


SMALL

= SMALL ( cell_range_angka , nth )


Penulisan kedua rumus tersebut mirip, bukan? Tinggal masukkan input cell range angkamu dan urutan angka yang kamu ingin dapatkan ke LARGE/SMALL.

Berikut contoh implementasi mereka di excel.

Cara Membuat Ranking/Peringkat di Excel dengan Berbagai Rumus Ranking Excel - Screenshot Contoh Implementasi Rumus LARGE/SMALL

Di sini, kita ingin mendapatkan kuantitas penjualan terbesar ketiga dan terkecil kelima dari data kuantitas penjualan bulanannya. Untuk mendapatkan kuantitas-kuantitas penjualan tersebut, kita gunakan rumus LARGE dan SMALL.

Tinggal masukkan input cell range kolom kuantitas penjualannya dan urutan angka yang ingin kita dapatkan ke rumus LARGE/SMALL. Pada contoh, kita masukkan input tiga ke LARGE dan input lima ke SMALL untuk input urutan angkanya.

Tuliskan rumus LARGE/SMALLmu dengan benar dan kamu akan mendapatkan nilai terbesar/terkecil ke-n yang kamu inginkan!



Latihan

Setelah kamu mempelajari cara membuat ranking/peringkat di excel secara lengkap, sekarang mari kita kerjakan latihan. Kerjakan agar kamu bisa mempraktekkan apa yang baru saja kamu pelajari dan memahami pembelajaran dari tutorialnya dengan lebih baik.

Unduh file latihan di bawah ini dan jawab semua pertanyaannya. Unduh file kunci jawabannya jika kamu sudah menyelesaikan latihannya dan ingin mengecek jawabanmu!

Link file latihan:
Unduh di sini

Pertanyaan

Jawab setiap pertanyaan di bawah ini di kolom berwarna abu-abu yang sesuai dengan nomor pertanyaannya!
  1. Rangking kuantitas persediaannya secara normal dalam urutan dari kecil ke besar!
  2. Rangking kuantitas persediaannya berdasarkan kelompok produknya dalam urutan dari besar ke kecil!
  3. Rangking kuantitas persediaan dari gudang II, VI, dan VIII dalam urutan dari besar ke kecil!

Link file kunci jawaban:
Unduh di sini



Catatan Tambahan

Kamu juga bisa merangking data tanggal dan waktu di excel karena mereka juga berjenis data angka. Rangking mereka dengan menggunakan cara yang kamu gunakan untuk merangking angka.



Tutorial terkait yang sebaiknya kamu pelajari juga:



Ingin Belajar Lebih Banyak Tentang Excel?


Dapatkan info excel terbaru dari Compute Expert dengan mendaftarkan emailmu. Gratis!


Ingin Belajar Lebih Banyak Tentang Excel?


Dapatkan info excel terbaru dari Compute Expert dengan mendaftarkan emailmu. Gratis!



Ikuti konten tutorial kami juga di




Tutorial Pilihan CE

Cara Menghitung di Excel

Cara Menjumlahkan di Excel

Cara Pengurangan di Excel

Cara Mengalikan di Excel

Cara Membagi di Excel

Cara Menghitung Rata-rata di Excel



Rumus Excel

Rumus VLOOKUP

Rumus IF Excel

Rumus SUM Excel

Rumus COUNTIF Excel

Rumus COUNT



Tips dan Trik Excel

Cara Print Excel

Rumus Terbilang Excel

Worksheet Adalah

Range Adalah

Cara Menambah Kolom di Excel



Konsultasi Excel

Kontak Kami

Kebijakan Privasi

Kebijakan Afiliasi

Syarat & Ketentuan



© 2021 Compute Expert